***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr. 11, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5530-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.216
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=150.2  VTO=2.2  LEVEL=3  VMAX=5e4  ETA=0.006 gamma=0.78 nfs=6.532e11)
Rd     d1    d2    5.404e-3    TC=4.0m,7u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=33  TBV1=4.405e-4 TBV2=5.05e-9  CJO=6.165e-10  M=8.283e-1  VJ=7.814)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=6.648e-19  N=6.079e-1 RS=4e-8  EG=1.10  TT=20n IKF=3.911e-2 tikf=7.5e-4)
Rdiode  d1  21    4.507e-3 TC=2.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   2.659e-10
.MODEL     DGD    D(CJO=2.659e-10   M=9.509e-1   VJ=8.658)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    3.326e-10
.ENDS PJQ5530-AU
*$
